Cara Membuat Script Close OP Buy & Sell

Belajar Script MQL4 - Cara Membuat Script Close OP Buy & Sell (Script Close Order All).

10 Langkah Membuat Script Close All Order Dengan MQL4:

1. Buka Metatrader4.
2. Tekan F4.
3. Tekan Ctrl + N.
4. Klik Lingkaran Script dan klik Next.
5. Kolom Name isi dengan Script Close OP Buy & Sell.
6. Kolom Author isi dengan Admin.
7. Kolom Link isi dengan URL website http://kursusforex.net
8. Klik tombol Finish.
9. Tulis coding MQL4 untuk membuat script close op buy dan sell.
10. Kalau sudah klik Compile.

Gambar 1 Variable Untuk Membuat Script Close All Order:

Gambar 2 Coding MQL4 Untuk Membuat Script Close All Order:

Gambar 3 Coding MQL4 Untuk Membuat Script Close OP Buy dan Sell:

Untuk Memudahkan Kalian Dalam Membuat Script Close OP Buy dan Sell Pelajari Coding MQL4 diBawah Ini!

//+------------------------------------------------------------------+

//|                                   SCRIPT CLOSE OP BUY & SELL.mq4 |

//|                                                           addmin |

//|                                      http://kursusforex.net |

//+------------------------------------------------------------------+

#property copyright "copyright @ admin"

#property link      "http://solo.kursusforex.net"

#property version   "1.00"

#property strict

Di atas adalah coding dasar template mql4 untuk membuat script. 

#property show_inputs

enum ENUM_ORDER_TYPES{

   ALL_ORDERS=1,  //BUY & SELL

   ONLY_BUY=2,    //BUY SAJA

   ONLY_SELL=3    //SELL SAJA

};

input bool OnlyCurrentSymbol=false;   //Close OP Hanya di Chart

input ENUM_ORDER_TYPES OrderTypeFilter=ALL_ORDERS;//OP Yg di Close

input bool OnlyInProfit=false;        //Close OP Hanya Yang Laba

input bool OnlyInLoss=false;          //Close OP Hanya Yang Rugi

      bool OnlyMagicNumber=false; //Close OP Hanya Yg Cocok Dgn Magic Number

      int MagicNumber=0;              //Magic Number Yang Cocok

      bool OnlyWithComment=false;     //Close OP Hanya Dengan Komentar

      string MatchingComment="";      //Komentar Yang Cocok

      int Slippage=2;                 //Slippage

      int Delay=0;                    //Close Delay

Di atas adalah coding variable untuk membuat script close order all.

//+------------------------------------------------------------------+

//| Script program start function                                    |

//+------------------------------------------------------------------+  

void OnStart(){

   CloseOrders();   

}       

      

void CloseOrders(){

  

   RefreshRates();

   Print(OrdersTotal());

      

   for(int i=(OrdersTotal()-1);i>=0;i--){

      

      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES)==false){

         Print("Tidak Dapat Memilih Order - Error - ",GetLastError());

         break;

      } 

      if(OrderTypeFilter==ONLY_SELL && OrderType()==OP_BUY) continue;    

      if(OrderTypeFilter==ONLY_BUY && OrderType()==OP_SELL) continue;    

      if(OnlyCurrentSymbol && OrderSymbol()!=Symbol()) continue;

      if(OnlyInProfit && OrderProfit()<=0) continue;

      if(OnlyInLoss && OrderProfit()>=0) continue;

      if(OnlyMagicNumber && OrderMagicNumber()!=MagicNumber) continue;

      if(OnlyWithComment && StringCompare(OrderComment(),MatchingComment)!=0) continue;

      

      bool res=false;

      

      double BidPrice=MarketInfo(OrderSymbol(),MODE_BID);

      double AskPrice=MarketInfo(OrderSymbol(),MODE_ASK);

      if(OrderType()==OP_BUY){

         res=OrderClose(OrderTicket(),OrderLots(),BidPrice,Slippage);

      }

      if(OrderType()==OP_SELL){

         res=OrderClose(OrderTicket(),OrderLots(),AskPrice,Slippage);

      }

      

      if(res==false) Print("Gagal Close Order - Error ",OrderTicket()," - ",GetLastError());

   

      Sleep(Delay);

   }

}

Di atas adalah coding mql4 untuk membuat script close all order.

Kalau Teman - Teman Ada Pertanyaan Terkait Dengan Belajar Script MQL4, Cara Membuat Script Close OP Buy & Sell, Silahkan Tulis diKolom Comment atau Langsung Hubungi ke Kontak Kami!